#1
  1. No Profile Picture
    Contributing User
    ASP Adventurer (500 - 999 posts)

    Join Date
    Feb 2005
    Location
    London England
    Posts
    640
    Rep Power
    13

    Adding blank record into database


    Good day all, I'm seriously rusty.

    I have some code that uploads a file and should add a record to my database. The code compiles with no errors, the file is uploaded but a blank record is added to my database.

    I'm not sure why it isn't working. I suspect the line in bold is not quite right...

    As always any assistance would be great.

    Code:
    <!--#include file="clsUpload.asp"-->
    
    <%
    'Check if user is logged in
    if Session("name") = "" then
    	'If not, go to login page
    	Response.Redirect("login.asp")
    else
    	'If, build page
    	Response.Write("<title>ASP Page</title>")
    	Response.write("<center>Welcome " & Session("name") & "<br><a href=logout.asp>Logout</a></center>")
    end if
    %>
    
    
    <FORM ACTION = "default.asp" ENCTYPE="multipart/form-data" METHOD="POST">
    
    <!--make this FileName-->
    
    Upload Date: <input type="text" name="txtFileUploadDate" id="txtFileUploadDate" value="<%response.write(date())%>" /><br />
    
    Job Type: <select name="txtJobType" id="txtJobType"><option value="Business">Business</option><option value="Personal">Personal</option></select><br />
    Job Service: <select name="txtJobService" id="txtJobService"><option value="Proofreading">Proofreading</option><option value="Copyediting">Copyediting</option></select><br />
    Job Language: <select name="txtJobLanguage" id="txtJobLanguage"><option value="Native">Native</option><option value="Non-native">Non-native</option></select><br />
    File Type: <select name="txtFileType" id="txtFileType"><option value="PDF">PDF</option><option value="DOC">DOC</option><option value="TXT">TXT</option><option value="HTML">HTML</option></select><br />
    File Name: <input type="file" name="txtFileName" id="txtFileName" /><br />
    Word Count: <input type="text" name="txtFileWordCount" id="txtFileWordCount" /><br />
    Comments: <textarea name="txtFileComments" id="txtFileComments" rows="2" /></textarea><br />
    Due Date: <input type="text" name="txtJobDueDate" id="txtJobDueDate" /><br />
    
    <INPUT TYPE = "SUBMIT" NAME="cmdSubmit" VALUE="SUBMIT">
    </FORM>
    <%
    
    	
    
    
    set o = new clsUpload
    if o.Exists("cmdSubmit") then
    
    
    set conn = server.CreateObject ("ADODB.Connection")
    	conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & server.MapPath ("db\users.mdb")
    	set rs = server.CreateObject ("ADODB.Recordset")
    	rs.Open "SELECT * FROM Jobs", conn, 3, 3 
    	rs.AddNew 
    
    	rs("FileUploadDate")=txtFileUploadDate
    	rs("JobType")=txtJobType
    	rs("JobService")=txtJobService
    	rs("JobLanguage")=txtJobLanguage
    	rs("FileType")=txtFileType
    	rs("FileName")=txtFileName
    	rs("FileWordCount")=txtFileWordCount
    	rs("FileComments")=txtFileComments
    	rs("JobDueDate")=txtJobDueDate
    	rs.Update 
    
    	set rs=nothing
    	set conn=Nothing
    	
    
    sFileSplit = split(o.FileNameOf("txtFileName"), "\")
    sFile = sFileSplit(Ubound(sFileSplit))
    
    o.FileInputName = "txtFileName"
    o.FileFullPath = Server.MapPath(".") & "\uploads\" & sFile
    o.save
    
     if o.Error = "" Then
    	response.write "<a href=""http://www.perfectproofreading.co.uk/uploads/" & sFile & """>View File</a>"
     else
    	response.write "Failed due to the following error: " & o.Error
     end if
    
    end if
    set o = nothing
    %>
  2. #2
  3. Contributing User
    ASP Skiller (1500 - 1999 posts)

    Join Date
    Mar 2005
    Location
    Columbus, OH
    Posts
    1,592
    Rep Power
    278
    your problem on line
    [CODE]if o.Exists("cmdSubmit") then [/CPDE]
    there you triggered condition if form submitted your self in addition you should check if form is not empty...
    to give you exact fix I need to see entire code not just peaces (from where you get value for txtFileUploadDate, txtJobType and etc.)
    GK
    __________________________________________________ _____
    if you found this post is useful click Give Rep button (bottom side on this reply ) and agree
  4. #3
  5. No Profile Picture
    Contributing User
    ASP Adventurer (500 - 999 posts)

    Join Date
    Feb 2005
    Location
    London England
    Posts
    640
    Rep Power
    13
    Hello GK, thank you for the timely response.

    Just to be clear this is my page in it's entirety. The form is within the code I pasted, I have highlighted it in bold.

    Thank you.

    Code:
    <!--#include file="clsUpload.asp"-->
    
    <%
    'Check if user is logged in
    if Session("name") = "" then
    	'If not, go to login page
    	Response.Redirect("login.asp")
    else
    	'If, build page
    	Response.Write("<title>ASP Page</title>")
    	Response.write("<center>Welcome " & Session("name") & "<br><a href=logout.asp>Logout</a></center>")
    end if
    %>
    
    
    <FORM ACTION = "default.asp" ENCTYPE="multipart/form-data" METHOD="POST">
    
    Upload Date: <input type="text" name="txtFileUploadDate" id="txtFileUploadDate" value="<%response.write(date())%>" /><br />
    
    Job Type: <select name="txtJobType" id="txtJobType"><option value="Business">Business</option><option value="Personal">Personal</option></select><br />
    Job Service: <select name="txtJobService" id="txtJobService"><option value="Proofreading">Proofreading</option><option value="Copyediting">Copyediting</option></select><br />
    Job Language: <select name="txtJobLanguage" id="txtJobLanguage"><option value="Native">Native</option><option value="Non-native">Non-native</option></select><br />
    File Type: <select name="txtFileType" id="txtFileType"><option value="PDF">PDF</option><option value="DOC">DOC</option><option value="TXT">TXT</option><option value="HTML">HTML</option></select><br />
    File Name: <input type="file" name="txtFileName" id="txtFileName" /><br />
    Word Count: <input type="text" name="txtFileWordCount" id="txtFileWordCount" /><br />
    Comments: <textarea name="txtFileComments" id="txtFileComments" rows="2" /></textarea><br />
    Due Date: <input type="text" name="txtJobDueDate" id="txtJobDueDate" /><br />
    
    <INPUT TYPE = "SUBMIT" NAME="cmdSubmit" VALUE="SUBMIT">
    </FORM>
    <%
    
    	
    
    
    set o = new clsUpload
    if o.Exists("cmdSubmit") then
    
    
    set conn = server.CreateObject ("ADODB.Connection")
    	conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & server.MapPath ("db\users.mdb")
    	set rs = server.CreateObject ("ADODB.Recordset")
    	rs.Open "SELECT * FROM Jobs", conn, 3, 3 
    	rs.AddNew 
    
    	rs("FileUploadDate")=txtFileUploadDate
    	rs("JobType")=txtJobType
    	rs("JobService")=txtJobService
    	rs("JobLanguage")=txtJobLanguage
    	rs("FileType")=txtFileType
    	rs("FileName")=txtFileName
    	rs("FileWordCount")=txtFileWordCount
    	rs("FileComments")=txtFileComments
    	rs("JobDueDate")=txtJobDueDate
    	rs.Update 
    
    	set rs=nothing
    	set conn=Nothing
    	
    
    sFileSplit = split(o.FileNameOf("txtFileName"), "\")
    sFile = sFileSplit(Ubound(sFileSplit))
    
    o.FileInputName = "txtFileName"
    o.FileFullPath = Server.MapPath(".") & "\uploads\" & sFile
    o.save
    
     if o.Error = "" Then
    	response.write "<a href=""http://www.perfectproofreading.co.uk/uploads/" & sFile & """>View File</a>"
     else
    	response.write "Failed due to the following error: " & o.Error
     end if
    
    end if
    set o = nothing
    %>
  6. #4
  7. Contributing User
    ASP Skiller (1500 - 1999 posts)

    Join Date
    Mar 2005
    Location
    Columbus, OH
    Posts
    1,592
    Rep Power
    278
    In this case your database has empty record even if you fill the form...

    you should have something like

    rs("FileUploadDate")=o.form("txtFileUploadDate")

    because variable txtFileUploadDate not assigned anywhere before...
  8. #5
  9. No Profile Picture
    Contributing User
    ASP Adventurer (500 - 999 posts)

    Join Date
    Feb 2005
    Location
    London England
    Posts
    640
    Rep Power
    13
    Microsoft VBScript runtime error '800a01b6'

    Object doesn't support this property or method: 'form'

    /default.asp, line 50


    Code:
    <!--#include file="clsUpload.asp"-->
    
    <%
    'Check if user is logged in
    if Session("name") = "" then
    	'If not, go to login page
    	Response.Redirect("login.asp")
    else
    	'If, build page
    	Response.Write("<title>ASP Page</title>")
    	Response.write("<center>Welcome " & Session("name") & "<br><a href=logout.asp>Logout</a></center>")
    end if
    %>
    
    
    <FORM ACTION ="default.asp" ENCTYPE="multipart/form-data" METHOD="POST">
    
    Upload Date: <input type="text" name="txtFileUploadDate" id="txtFileUploadDate" value="<%response.write(date())%>" /><br />
    
    Job Type: <select name="txtJobType" id="txtJobType"><option value="Business">Business</option><option value="Personal">Personal</option></select><br />
    Job Service: <select name="txtJobService" id="txtJobService"><option value="Proofreading">Proofreading</option><option value="Copyediting">Copyediting</option></select><br />
    Job Language: <select name="txtJobLanguage" id="txtJobLanguage"><option value="Native">Native</option><option value="Non-native">Non-native</option></select><br />
    File Type: <select name="txtFileType" id="txtFileType"><option value="PDF">PDF</option><option value="DOC">DOC</option><option value="TXT">TXT</option><option value="HTML">HTML</option></select><br />
    File Name: <input type="file" name="txtFileName" id="txtFileName" /><br />
    Word Count: <input type="text" name="txtFileWordCount" id="txtFileWordCount" /><br />
    Comments: <textarea name="txtFileComments" id="txtFileComments" rows="2" /></textarea><br />
    Due Date: <input type="text" name="txtJobDueDate" id="txtJobDueDate" /><br />
    
    <INPUT TYPE = "SUBMIT" NAME="cmdSubmit" VALUE="SUBMIT">
    </FORM>
    <%
    
    
    
    
    	
    
    set o = new clsUpload
    if o.Exists("cmdSubmit") then
    
    sFileSplit = split(o.FileNameOf("txtFileName"), "\")
    sFile = sFileSplit(Ubound(sFileSplit))
    
    set conn = server.CreateObject ("ADODB.Connection")
    	conn.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & server.MapPath ("db\users.mdb")
    	set rs = server.CreateObject ("ADODB.Recordset")
    	rs.Open "SELECT * FROM Jobs", conn, 3, 3 
    	rs.AddNew 
    
     rs("FileUploadDate") = o.form("txtFileUploadDate")
     rs.Update 
    
    	set rs=nothing
    	set conn=Nothing
    
    o.FileInputName = "txtFileName"
    o.FileFullPath = Server.MapPath(".") & "\uploads\" & sFile
    o.save
    
     if o.Error = "" Then
    	response.write "<a href=""http://www.perfectproofreading.co.uk/uploads/" & sFile & """>View File</a>"
     else
    	response.write "Failed due to the following error: " & o.Error
     end if
    
    end if
    set o = nothing
    %>
  10. #6
  11. Contributing User
    ASP Skiller (1500 - 1999 posts)

    Join Date
    Mar 2005
    Location
    Columbus, OH
    Posts
    1,592
    Rep Power
    278
    I do not know what object you are using for file upload.. what is set o = new clsUpload just guessing...
    look on documentation on file upload component you are using
  12. #7
  13. No Profile Picture
    Contributing User
    ASP Adventurer (500 - 999 posts)

    Join Date
    Feb 2005
    Location
    London England
    Posts
    640
    Rep Power
    13
    Hi, clsUpload in the include file. Here is the code.

    Code:
    <%
    ' ------------------------------------------------------------------------------
    ' Container of Field Properties
    Class clsField
    	Public FileName
    	Public ContentType
    	Public Value
    	Public FieldName
    	Public Length
    	Public BinaryData
    End Class
    ' ------------------------------------------------------------------------------
    Class clsUpload
    ' ------------------------------------------------------------------------------
    	Private nFieldCount
    	Private oFields()
    	Private psFileFullPath
    	Private psError
    	Private psFileInputName
    ' ------------------------------------------------------------------------------
    	Public Property Get Count()
    		Count = nFieldCount
    	End Property
    ' ------------------------------------------------------------------------------
    	Public Default Property Get Field(ByRef asFieldName)
    		Dim lnLength
    		Dim lnIndex
    		
    		lnLength = UBound(oFields)
    		
    		If IsNumeric(asFieldName) Then
    			If lnLength >= asFieldName And asFieldName > -1 Then
    				Set Field = oFields(asFieldName)
    			Else
    				Set Field = New clsField
    			End If
    		Else
    			For lnIndex = 0 To lnLength
    				If LCase(oFields(lnIndex).FieldName) = LCase(asFieldName) Then
    					Set Field = oFields(lnIndex)
    					Exit Property
    				End If
    			Next
    			Set Field = New clsField
    		End If
    	End Property
    ' ------------------------------------------------------------------------------
    	Public Function Exists(ByRef avKeyIndex)
    		Exists = Not IndexOf(avKeyIndex) = -1
    	End Function
    ' ------------------------------------------------------------------------------
    	Public Property Get ValueOf(ByRef avKeyIndex)
    		Dim lnIndex
    		lnIndex = IndexOf(avKeyIndex)
    		if lnIndex = -1 Then Exit Property
    		ValueOf = oFields(lnIndex).Value
    	End Property
    ' ------------------------------------------------------------------------------
    	Public Property Get FileNameOf(ByRef avKeyIndex)
    		Dim lnIndex
    		lnIndex = IndexOf(avKeyIndex)
    		if lnIndex = -1 Then Exit Property
    		FileNameOf = oFields(lnIndex).FileName
    	End Property
    ' ------------------------------------------------------------------------------
    	Public Property Get LengthOf(ByRef avKeyIndex)
    		Dim lnIndex
    		lnIndex = IndexOf(avKeyIndex)
    		if lnIndex = -1 Then Exit Property
    		LengthOf = oFields(lnIndex).Length
    	End Property
    ' ------------------------------------------------------------------------------
    	Public Property Get BinaryDataOf(ByRef avKeyIndex)
    		Dim lnIndex
    		lnIndex = IndexOf(avKeyIndex)
    		if lnIndex = -1 Then Exit Property
    		BinaryDataOf = oFields(lnIndex).BinaryData
    	End Property
    ' ------------------------------------------------------------------------------
    	Private Function IndexOf(ByVal avKeyIndex)
    		Dim lnIndex
    		
    		If avKeyIndex = "" Then
    			IndexOf = -1
    		ElseIf IsNumeric(avKeyIndex) Then
    			avKeyIndex = CLng(avKeyIndex)
    			If nFieldCount > avKeyIndex And avKeyIndex > -1 Then
    				IndexOf = avKeyIndex
    			Else
    				IndexOf = -1
    			End If
    		Else
    			For lnIndex = 0 To nFieldCount - 1
    				If LCase(oFields(lnIndex).FieldName) = LCase(avKeyIndex) Then
    					IndexOf = lnIndex
    					Exit Function
    				End If
    			Next
    			IndexOf = -1
    		End If
    	End Function
    ' ------------------------------------------------------------------------------
    Public Property Let FileFullPath(sValue)
    	psFileFullPath = sValue
    End Property
    '___________________________________________________________________________________
    Public Property Get FileFullPath()
    	FileFullPath = psFileFullPath 
    End Property
    ' ------------------------------------------------------------------------------
    Public Property Let FileInputName(sValue)
    	psFileInputName = sValue
    End Property
    ' --------------------	----------------------------------------------------------
    Public Function Save()
    	if psFileFullPath <> "" and psFileInputName <> "" then
    		'Save to connectionless client side recordset, write to stream,
    		'and persist stream.
    
    		'would think you should be able to write directly to
    		'stream without recordset, but I could not get that to work
    
    		On error resume next
    		binData = o.BinaryDataOf(psFileInputName)
    	
    		set rs = server.createobject("ADODB.RECORDSET")
    		rs.fields.append "FileName", 205, LenB(binData)
    		rs.open
    		rs.addnew
     		rs.fields(0).AppendChunk binData 
    		
    		if err.number = 0 then
    			set objStream = Server.CreateObject("ADODB.Stream")
      			objStream.Type  = 1
       			objStream.Open
     			objStream.Write rs.fields("FileName").value 
    			objStream.SaveToFile psFileFullPath, 2
    			objStream.close
    			set objStream = Nothing
    
    		ENd if
    		rs.close
    		set rs = nothing
    		psError = Err.Description
    else
    		psError = "One or more required properties (FileFullPath and/or FileInputName) not set"
    
      End If
    
    
    End Function
    
    Public Property Get Error()
    	Error = psError
    End Property
    
    
    ' ------------------------------------------------------------------------------
    	Public Property Get ContentTypeOf(ByRef avKeyIndex)
    		Dim lnIndex
    		lnIndex = IndexOf(avKeyIndex)
    		if lnIndex = -1 Then Exit Property
    		ContentTypeOf = oFields(lnIndex).ContentType
    	End Property
    
    ' ------------------------------------------------------------------------------
    	Private Sub Class_Terminate()
    		Dim lnIndex
    		For lnIndex = 0 To nFieldCount - 1
    			Set oFields(0) = Nothing
    		Next
    	End Sub
    ' ------------------------------------------------------------------------------
    	Private Sub Class_Initialize()
    		
    		Dim lnBytes				' Bytes received from the client
    		Dim lnByteCount			' Number of bytes received
    		Dim lnStartPosition		' Position at which content begins
    		Dim lnEndPosition		' Position at which content ends
    		
    		Dim loDic				' Contains properties of each
    								' specific field
    								' Local dictionary object(s) 
    								' to be appended to class-scope
    								' dictioary object.
    								
    		Dim lnBoundaryBytes		' Bytes contained within the current boundary
    		Dim lnBoundaryStart		' Position at wich the current boundary begins
    								' within the lnBytes binary data.
    		Dim lnBoundaryEnd		' Position at wich the current boundary ends
    								' within the lnBytes binary data.
    		Dim lnDispositionPosition
    		
    		Dim lsFieldName			' Name of the current field being parsed from
    								' Binary Data
    		Dim lsFileName			' Name of the file within the current boundary
    		Dim lnFileNamePosition	' Location of file name within current boundary
    		Dim loField				' clsField Object
    		Dim lsValue				' Value of the current field
    		Dim lsContentType		' ContentType of the binary file (MIME Type)
    		
    		' Initialize Fields
    		nFieldCount = 0
    		ReDim oFields(-1)
    		
    		' Read the bytes (binary data) into memory	
    		lnByteCount = Request.TotalBytes
    		lnBytes = Request.BinaryRead(lnByteCount)
    		
    		'Get the lnBoundaryBytes
    		lnStartPosition = 1
    		lnEndPosition = InstrB(lnStartPosition, lnBytes, CStrB(vbCr))
    		
    		If lnEndPosition >= lnStartPosition Then
    			lnBoundaryBytes = MidB(lnBytes, lnStartPosition, lnEndPosition - lnStartPosition)
    		End If
    		
    		lnBoundaryStart = InstrB(1, lnBytes, lnBoundaryBytes)
    		
    		
    		' Loop until the BoundaryBytes begin with "--"
    		Do Until (lnBoundaryStart = InstrB(lnBytes, lnBoundaryBytes & CStrB("--")))
    		
    			' All data within this boundary is stored within a local dictionary
    			' to be appended to the class-scope dictionary.
    			
    			ReDim Preserve oFields(nFieldCount)
    			nFieldCount = nFieldCount + 1
    			
    			Set loField = New clsField
    
    			lnDispositionPosition = InstrB(lnBoundaryStart, lnBytes, CStrB("Content-Disposition"))
    			
    			' Get an object name
    			lnStartPosition = InstrB(lnDispositionPosition, lnBytes, CStrB("name=")) + 6
    			lnEndPosition = InstrB(lnStartPosition, lnBytes, CStrB(""""))
    			lsFieldName = CStrU(MidB(lnBytes, lnStartPosition, lnEndPosition - lnStartPosition))
    			loField.FieldName = lsFieldName
    			
    			' Get the location fo the file name.
    			lnFileNamePosition = InstrB(lnBoundaryStart, lnBytes, CStrB("filename="))
    			lnBoundaryEnd = InstrB(lnEndPosition, lnBytes, lnBoundaryBytes)
    			
    			'Test if object is a file
    			If Not lnFileNamePosition = 0 And lnFileNamePosition < lnBoundaryEnd Then
    			
    				' Parse Filename
    				lnStartPosition = lnFileNamePosition + 10
    				lnEndPosition =  InstrB(lnStartPosition, lnBytes, CStrB(""""))
    				lsFileName = CStrU(MidB(lnBytes,lnStartPosition,lnEndPosition-lnStartPosition))
    				loField.FileName = lsFileName				
    				
    				' Parse Content-Type
    				lnStartPosition = InstrB(lnEndPosition,lnBytes,CStrB("Content-Type:")) + 14
    				lnEndPosition = InstrB(lnStartPosition,lnBytes,CStrB(vbCr))
    				lsContentType = CStrU(MidB(lnBytes,lnStartPosition,lnEndPosition-lnStartPosition))
    				loField.ContentType = lsContentType
    
    				' Parse Content
    				lnStartPosition = lnEndPosition + 4
    				lnEndPosition = InstrB(lnStartPosition,lnBytes,lnBoundaryBytes)-2
    				lsValue = MidB(lnBytes,lnStartPosition,lnEndPosition-lnStartPosition)
    				loField.BinaryData = lsValue & CStrB(vbNull)
    				loField.Length = LenB(lsValue)
    			Else
    
    				' Parse Content
    				lnStartPosition = InstrB(lnDispositionPosition, lnBytes, CStrB(vbCr)) + 4
    				lnEndPosition = InstrB(lnStartPosition, lnBytes, lnBoundaryBytes) - 2
    				lsValue = CStrU(MidB(lnBytes,lnStartPosition,lnEndPosition-lnStartPosition))
    				loField.Value = lsValue
    				loField.Length = Len(lsValue)
    			End If
    
    			Set oFields(UBound(oFields)) = loField
    
    			'Loop to next object
    			lnBoundaryStart = InstrB(lnBoundaryStart + LenB(lnBoundaryBytes), lnBytes, lnBoundaryBytes)
    			
    			Set loField = Nothing
    			
    		Loop
    
    	End Sub
    ' ------------------------------------------------------------------------------
    	Private Function CStrU(ByRef psByteString)
    		Dim lnLength
    		Dim lnPosition
    		lnLength = LenB(psByteString)
    		For lnPosition = 1 To lnLength
    			CStrU = CStrU & Chr(AscB(MidB(psByteString, lnPosition, 1)))
    		Next
    	End Function
    ' ------------------------------------------------------------------------------
    	Private Function CStrB(ByRef psUnicodeString)
    		Dim lnLength
    		Dim lnPosition
    		lnLength = Len(psUnicodeString)
    		For lnPosition = 1 To lnLength
    			CStrB = CStrB & ChrB(AscB(Mid(psUnicodeString, lnPosition, 1)))
    		Next
    	End Function
    ' ------------------------------------------------------------------------------
    End Class
    ' ------------------------------------------------------------------------------
    %>
  14. #8
  15. Contributing User
    ASP Skiller (1500 - 1999 posts)

    Join Date
    Mar 2005
    Location
    Columbus, OH
    Posts
    1,592
    Rep Power
    278
    it looks like
    you need to change
    rs("FileUploadDate") = o.form("txtFileUploadDate")
    to
    rs("FileUploadDate") = o.Field("txtFileUploadDate").value
    or
    rs("FileUploadDate") = o.Field("txtFileUploadDate")

Similar Threads

  1. Adding a record into a database table
    By zeetec1 in forum .NET Development
    Replies: 3
    Last Post: July 2nd, 2008, 09:35 AM
  2. Urgent! : Adding record to database!
    By vivek_vt in forum ASP Development
    Replies: 25
    Last Post: July 5th, 2007, 06:44 AM
  3. Adding record to database?
    By werD in forum ASP Development
    Replies: 9
    Last Post: January 24th, 2005, 05:50 AM
  4. help, problems when adding record to database.
    By HareshKainth in forum Microsoft Access Help
    Replies: 1
    Last Post: July 14th, 2004, 07:42 AM
  5. Adding record to Access Database
    By Steve Schofield in forum ASP Development
    Replies: 1
    Last Post: October 30th, 2000, 07:06 PM

IMN logo majestic logo threadwatch logo seochat tools logo