Sending Emails using CDO.Message component

 <%
 Const SMTP_SERVER="smtpserver.domain.com"
 
 '--------------------------------------------------------------------
 'SendEmail:
 'Try to send given email using CDO component.
 'Returns empty string in case of success or error message in case of error.
 '--------------------------------------------------------------------
Function SendEmail(strEmailTo, strEmailFrom, strEmailSubject, strEmailBody, arrAttachments)
	'declare variables
	Dim objMessage	'object for sending email
	Dim objConf	'object for configuration of email settings
	Dim x		'loop iterator
	
	'define default return value:
	SendEmail=""
	
	'create objects:
	Set objMessage=Server.CreateObject("CDO.Message")
	Set objConf=Server.CreateObject("CDO.Configuration")
	
	'define settings:
	If Len(SMTP_SERVER)=0 Then
		objConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing")=1
	Else  
		objConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing")=2 'cdoSendUsingPort
	End If
	objConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverpickupdirectory")=Server.MapPath("/")
	If Len(SMTP_SERVER)>0 Then
	    objConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver")=SMTP_SERVER
	End If
	objConf.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport")=25
	objConf.Fields.Update
	
	'apply settings:
	Set objMessage.Configuration=objConf
	
	'build message details:
	objMessage.To=strEmailTo
	objMessage.From=strEmailFrom
	objMessage.Subject=strEmailSubject
	objMessage.HtmlBody=strEmailBody
	
	If IsArray(arrAttachments) Then
		For x=0 To UBound(arrAttachments)
			objMessage.AddAttachment arrAttachments(x)
		Next
	End If
	
	'catch errors and try to send:
	On Error Resume Next
		objMessage.Send
		If Err.Number<>0 Then
			SendEmail=Err.Description
			Err.Clear
		End If
	On Error Goto 0
	
	'done, clear objects from the memory:
 	Set objMessage=Nothing
 	Set objConf=Nothing
End Function

'usage:
Dim strError
strError = SendEmail("someone@somewhere.com", "test <test@test.com>", "testing without attachments", "hello world", "")
If Len(strError)=0 Then
	Response.Write("success!<br />")
Else  
	Response.Write("failure: " & strError & "<br />")
End If
strError = SendEmail("someone@somewhere.com", "test <test@test.com>", "testing with attachments", "hello world", Array(Server.MapPath("file1.txt"), Server.MapPath("file2.asp")))
If Len(strError)=0 Then
	Response.Write("success!")
Else  
	Response.Write("failure: " & strError & "<br />")
End If
 %>
 

	If IsArray(arrAttachments) Then
		For x=0 To UBound(arrAttachments)
			objMessage.AddAttachment arrAttachments(x)
		Next
	End If

strError = SendEmail("someone@somewhere.com", "test <test@test.com>", "testing with attachments", "hello world", Array(Server.MapPath("file1.txt"), Server.MapPath("file2.asp")))