Vbscript - automatic parsing of links inside text

<% Option Explicit %>
<%
Function AddLinks(strText)
	Dim result, arrWords, x
	Dim curWord, blnLinkActive
	result=""
	arrWords=Split(strText, " ")
	blnLinkActive = False
	For x=0 TO UBound(arrWords)
		curWord=arrWords(x)
		If LCase(curWord)="<a" Then
			blnLinkActive = True
		End If
		If LCase(curWord)="</a>" Then
			blnLinkActive = False
		End If
		If Not(blnLinkActive) Then
			If IsURL(curWord) Then
				curWord="<a href=""" & MakeFullURL(curWord) & """>" & curWord & "</a>"
			End If
		End If
		result = result & curWord
		If x<UBound(arrWords) Then result=result&" "

	Next
	Erase arrWords
	AddLinks=result
End Function

Function IsURL(strText)
	Dim arrTmp
	IsURL=True
	If BeginsWith(strText, "http://") Then Exit Function
	If BeginsWith(strText, "https://") Then Exit Function
	arrTmp=Split(strText, ".")
	If UBound(arrTmp)>1 Then
		If FindInArray(arrTmp, " ")=0 Then
			If IsValidDomain( arrTmp(UBound(arrTmp)) ) Then
				Erase arrTmp
				Exit Function
			End If
		End If
	End If
	Erase arrTmp
	IsURL=False
End Function

Function MakeFullURL(strText)
	Dim result
	If (Not(BeginsWith(strText, "http://"))) And (Not(BeginsWith(strText, "https://"))) Then
		result = "http://"
	End If
	result = result & strText
	MakeFullURL = result
End Function

Function BeginsWith(strBig, strSmall)
	BeginsWith = (Left(LCase(strBig), Len(strSmall))=LCase(strSmall))
End Function

Function FindInArray(arr, strToFind)
	Dim x, result
	result=0
	For x=0 To UBound(arr)
		If InStr(1, arr(x), strToFind, 1)>0 Then result=result+1
	Next
	FindInArray=result
End Function

Function IsValidDomain(str)
	'optional.... if you want, have list of all available domains and compare.
	IsValidDomain=True
End Function

Dim strText
strText="hello please go to http://www.google.com and visit us again at ynet.co.il"
Response.Write(AddLinks(strText))
%>

Original - asp Code <% Function parseURL(strText) Set regEx = New RegExp regEx.Global = true regEx.IgnoreCase = True regEx.Pattern = "(\b(ht|f)tp(s?)://[^ ]+\b)" parseURL = regEx.Replace(strText,"<a href=""$1"">$1</a>") End Function Dim strings(4) strings(0) = "Hello there, please visit http://www.google.com to search for things" strings(1) = "https://domain.com is a secure address" strings(2) = "An FTP site will be in the format of ftp://domain.com" strings(3) = "It could also have a username; ftp://user@ftp.domain.com" strings(4) = "http://www.domain.co.uk/folder/page.ext?var=val" For Each str In strings Response.Write parseURL(str) & "<br>" Next %>

<%
Function parseURL(strText)
  Set regEx = New RegExp
  regEx.Global = true
  regEx.IgnoreCase = True
  regEx.Pattern = "(\b(ht|f)tp(s?)://[^ ]+\b)"
  parseURL = regEx.Replace(strText,"<a href=""$1"">$1</a>")
End Function
 
Dim strings(4)
strings(0) = "Hello there, please visit http://www.google.com to search for things"
strings(1) = "https://domain.com is a secure address"
strings(2) = "An FTP site will be in the format of ftp://domain.com"
strings(3) = "It could also have a username; ftp://user@ftp.domain.com"
strings(4) = "http://www.domain.co.uk/folder/page.ext?var=val"
 
For Each str In strings
    Response.Write parseURL(str) & "<br>"
Next
%> 

strings(0) = "Hello there, please visit <a href=""http://www.google.com"">http://www.google.com</a> to search for things"