Total price in Other Currency (Real time rate)

<%
' Parameters
GBL_URL = "http://www.webservicex.net/CurrencyConvertor.asmx/ConversionRate?FromCurrency=#From#&ToCurrency=#To#"
GBL_FROM = "AUD"
GBL_TO = "USD"
%>
<%
' Strip HTML tags from a string
Function RemoveHTML( str_HTMLString )
Dim RegExp
Set RegExp = New RegExp
RegExp.Pattern = "<[^>]*>"
RegExp.Global = True
str_HTMLString = Replace(LCase(str_HTMLString), "<br>", chr(10))
RemoveHTML = RegExp.Replace(str_HTMLString, "")
End Function
' Collect a remote URL response
Function GetURL( str_URL )
Set obj_XMLHTTP = Server.CreateObject ("Microsoft.XMLHTTP") 
obj_XMLHTTP.Open "GET", str_URL, False, "", "" 
obj_XMLHTTP.Send()
If Err.Number = 0 Then
If obj_XMLHTTP.Status = 200 Then
GetURL = obj_XMLHTTP.ResponseText
Else
GetURL = "*Error*"
End If
Else
GetURL = "*Error*"
End If 
Set obj_XMLHTTP = Nothing 
End Function
' Cleanup extraneous characters
Function Cleanup( str_String )
str_String = Replace(str_String,vbcrlf,"")
str_String = Replace(str_String,vbcr,"")
str_String = Replace(str_String,vblf,"")
Cleanup = str_String
End Function
%>
<%
' Use query string?
If Len(Request.QueryString("From")) = 3 Then GBL_FROM = UCase(Request.QueryString("From"))
If Len(Request.QueryString("To")) = 3 Then GBL_TO = UCase(Request.QueryString("To"))
' Format GET string
GBL_URL = Replace(GBL_URL,"#From#",GBL_FROM)
GBL_URL = Replace(GBL_URL,"#To#",GBL_TO)
' Get the URL and cleanup HTML tags and extraneous line feeds
str_GetURL = Cleanup(RemoveHTML(GetURL(GBL_URL)))
%>
1 <%= GBL_FROM %> = <%= str_GetURL %>&nbsp;<%= GBL_TO %>