Function to return path of Currentdb

Function ThisDB(Optional DesiredData As String = "fullpath") As String
'=================================================  ============================
'Copyright by Heather L. Floyd - Floyd Innovations - URL
' Updated 2-6-2004
'-----------------------------------------------------------------------------
' To return desired data about the current database file
'-----------------------------------------------------------------------------
' Parameters:
' ARGUEMENT                         :   DESCRIPTION
'-----------------------------------------------------------------------------
' DesiredData (Optional) (String)   :   String indicating what data you want
'                                       returned -
'                                       "fullpath" or "path" or "filename"
'                                       Default is "fullpath"
'-----------------------------------------------------------------------------
' Returns:
'   String of data requested based on 'DesiredData' arguement
'-----------------------------------------------------------------------------
' Example:
'-----------------------------------------------------------------------------
' ThisDB("fullpath") or ThisDB()= "C:\My Documents\My Database.mdb"
' ThisDB("path") = "C:\My Documents\"
' ThisDB("filename") = "My Database.mdb"
'=================================================  ============================

On Error GoTo ErrorCode


'Variables & values
    Dim db As DAO.Database
    Set db = CurrentDb()

    Dim strDB As String
    strDB = db.Name

    Dim strFullpath, strPath, strFileName As String
    strFullpath = strDB

    Dim iLenSDB As Integer
    Dim iDotLoc As Integer
    Dim iSlashLoc As Integer
    Dim strModSDB As String
    Dim iLenModSDB As Integer


    iLenSDB = Len(strDB)
    iDotLoc = InStr(strDB, ".")

    strModSDB = strDB
    iLenModSDB = Len(strModSDB)
    iSlashLoc = InStr(strDB, "\")

'Parse
    Do Until iSlashLoc = 0
        iLenModSDB = Len(strModSDB)
        strModSDB = Right(strModSDB, iLenModSDB - iSlashLoc)
        iSlashLoc = InStr(strModSDB, "\")
    Loop
    
    strFileName = strModSDB
    iLenModSDB = Len(strModSDB)
    strPath = Left(strDB, iLenSDB - iLenModSDB)

'Return value
    If DesiredData = "" Then
        ThisDB = strFullpath
    ElseIf DesiredData = "fullpath" Then
        ThisDB = strFullpath
    ElseIf DesiredData = "path" Then
        ThisDB = strPath
    ElseIf DesiredData = "filename" Then
        ThisDB = strFileName
    End If
    

ExitCode:
    Exit Function

ErrorCode:
    Select Case Err.number
        Case Else
            MsgBox "Error " & Err.number & ": " & Err.Description, vbCritical, "HLFFileUtils.ThisDB"
            Resume ExitCode
    End Select

End Function